LIBARY:
1.https://github.com/miguelbalboa/rfid
2.https://github.com/markub3327/LiquidCrystal_I2C



#include <SPI.h>
#include <MFRC522.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

#define SS_PIN 5
#define RST_PIN 4
#define BUZZER_PIN 25

MFRC522 rfid(SS_PIN, RST_PIN);
LiquidCrystal_I2C lcd(0x27, 16, 2);

byte UID_AKSES[] = {
  0xD3, 0xC0, 0x76, 0x28
};

bool cekUID() {
  if (rfid.uid.size != 4) {
    return false;
  }

  for (byte i = 0; i < 4; i++) {
    if (rfid.uid.uidByte[i] != UID_AKSES[i]) {
      return false;
    }
  }

  return true;
}

void setup() {
  Serial.begin(115200);

  pinMode(BUZZER_PIN, OUTPUT);

  // LCD
  Wire.begin(21, 22);
  lcd.init();
  lcd.backlight();

  // RFID
  SPI.begin(18, 19, 23, 5);
  rfid.PCD_Init();

  lcd.setCursor(0, 0);
  lcd.print("RFID SYSTEM");
  lcd.setCursor(0, 1);
  lcd.print("Tempelkan Kartu");

  delay(2000);
  lcd.clear();
}

void loop() {

  if (!rfid.PICC_IsNewCardPresent()) {
    return;
  }

  if (!rfid.PICC_ReadCardSerial()) {
    return;
  }

  Serial.print("UID: ");

  for (byte i = 0; i < rfid.uid.size; i++) {
    Serial.print(rfid.uid.uidByte[i], HEX);
    Serial.print(" ");
  }

  Serial.println();

  lcd.clear();

  if (cekUID()) {

    lcd.setCursor(0, 0);
    lcd.print("AKSES DITERIMA");

    lcd.setCursor(0, 1);
    lcd.print("Selamat Datang");

    tone(BUZZER_PIN, 2000);
    delay(300);
    noTone(BUZZER_PIN);

    Serial.println("DITERIMA");

  } else {

    lcd.setCursor(0, 0);
    lcd.print("AKSES DITOLAK");

    lcd.setCursor(0, 1);
    lcd.print("Kartu Tidak Sah");

    for (int i = 0; i < 3; i++) {
      tone(BUZZER_PIN, 1000);
      delay(200);
      noTone(BUZZER_PIN);
      delay(150);
    }

    Serial.println("DITOLAK");
  }

  delay(2000);

  lcd.clear();
  lcd.print("Tempelkan Kartu");

  rfid.PICC_HaltA();
  rfid.PCD_StopCrypto1();
}