Jam Digital Cerdas Berbasis NTP (Network Time Protocol)

Kode Program

#include <ESP8266WiFi.h>
#include <NTPClient.h>
#include <WiFiUdp.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128 // OLED display width, in pixels
#define SCREEN_HEIGHT 64 // OLED display height, in pixels
// Koneksi LCD -> SCL ke D1 dan SDA ke D2
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

WiFiUDP ntpUDP;
NTPClient timeClient(ntpUDP, "pool.ntp.org");

char ssid[] = "xxxxxxxxxx";  // Nama WiFi
char password[] = "xxxxxxxxxx";  // Password WiFi

#define buzzer 2
#define tombolJam 14
#define tombolMenit 12

int timezone = 7 * 3600;  // Zona waktu Indonesia (UTC+7)
int dst = 0;
int setJam = 0;
int setMenit = 0;
struct tm* p_tm;

void setup() {
  Serial.begin(9600);
  timeClient.begin();
  timeClient.setTimeOffset(timezone);  // Set timezone offset sesuai dengan zona waktu Indonesia (UTC+7)

  // Memulai komunikasi dengan layar OLED
  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    Serial.println(F("SSD1306 allocation failed"));
    for (;;);
  }
  display.clearDisplay();
  display.display();

  pinMode(tombolJam, INPUT_PULLUP);
  pinMode(tombolMenit, INPUT_PULLUP);
  pinMode(buzzer, OUTPUT);
  digitalWrite(buzzer, LOW);

  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0, 0);
  display.println("Wifi connecting to ");
  display.println(ssid);

  WiFi.begin(ssid, password);
  display.println("\nConnecting");
  display.display();

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    display.print(".");
    display.display();
  }

  // Setelah terhubung ke WiFi
  display.clearDisplay();
  display.display();
  display.setCursor(0, 0);
  display.println("Wifi Connected!");
  display.print("IP:");
  display.println(WiFi.localIP());
  display.display();
  display.println("\nTime response....OK");
  display.display();
  delay(1000);
  display.clearDisplay();
  display.display();
}

void loop() {
  // Update waktu dan tampilkan di layar
  clock_display();
  // Update alarm jika tombol ditekan
  set_alarm();
  // Jika waktunya cocok dengan alarm, aktifkan buzzer
  alarm();
}

void clock_display() {
  timeClient.update();
  String time = timeClient.getFormattedTime();

  time_t epochTime = timeClient.getEpochTime();
  struct tm *ptm = gmtime((time_t *)&epochTime);

  // Debugging, untuk memastikan waktu yang diterima benar
  Serial.print(ptm->tm_mday);
  Serial.print("/");
  Serial.print(ptm->tm_mon + 1);
  Serial.print("/");
  Serial.print(ptm->tm_year + 1900);
  Serial.print(" ");
  Serial.print(ptm->tm_hour);
  Serial.print(":");
  Serial.print(ptm->tm_min);
  Serial.print(":");
  Serial.println(ptm->tm_sec);

  // Menampilkan waktu di OLED
  display.clearDisplay();
  display.setTextSize(2);
  display.setTextColor(WHITE);
  display.setCursor(10, 10);
  display.print(time);
  display.setTextSize(1);
  display.setCursor(30, 0);
  display.print(ptm->tm_mday);
  display.print("/");
  display.print(ptm->tm_mon + 1);
  display.print("/");
  display.print(ptm->tm_year + 1900);
  display.setTextSize(1);
  display.setCursor(30, 30);
  display.print("SET ALARM");
  display.setTextSize(2);
  display.setCursor(35, 40);
  display.print(String(setJam) + ":" + String(setMenit));
  display.display();
  delay(1000); // Update setiap 1 detik
}

void set_alarm() {
  // Mengecek apakah tombol jam ditekan
  if (!digitalRead(tombolJam)) {
    Serial.println("Tambah jam");
    setJam++;
    if (setJam > 24) {
      setJam = 0;
    }
  }

  // Mengecek apakah tombol menit ditekan
  if (!digitalRead(tombolMenit)) {
    Serial.println("Tambah menit");
    setMenit++;
    if (setMenit > 59) {
      setMenit = 0;
    }
  }
}

void alarm() {
  int jamSekarang = timeClient.getHours();
  int menitSekarang = timeClient.getMinutes();

  if (jamSekarang == setJam && menitSekarang == setMenit) {
    buzzer_beep();
  }
}

void buzzer_beep() {
  digitalWrite(buzzer, HIGH);
  delay(100);
  digitalWrite(buzzer, LOW);
  delay(100);
  digitalWrite(buzzer, HIGH);
  delay(100);
  digitalWrite(buzzer, LOW);
  delay(100);
  digitalWrite(buzzer, HIGH);
  delay(100);
  digitalWrite(buzzer, LOW);
  delay(100);
  digitalWrite(buzzer, HIGH);
  delay(100);
  digitalWrite(buzzer, LOW);
  delay(100);
  digitalWrite(buzzer, HIGH);
  delay(100);
  digitalWrite(buzzer, LOW);
  delay(1000);
}